易语言窗口贴边隐藏模块及源码

.子程序 窗口贴边隐藏, , 公开, 靠边自动隐藏（顶边，左边，右边  3个位置），放置时钟事件下
.参数 窗口, 窗口, , 将要隐藏的窗口(_启动窗口)
.参数 是否拉伸, 逻辑型, 可空, 左右贴边时自动拉伸高度。 默认为“假”。 原高度
.参数 是否置顶, 逻辑型, 可空, 贴边时窗口是否置顶。 默认为“真”。 置顶
.局部变量 垂直座标, 整数型
.局部变量 水平座标, 整数型

' 今天闲着没事干，以前做的现在拿出来分享吧 - -
' 如果有什么BUG自己解决一下吧- -
处理事件 ()
垂直座标 ＝ 取鼠标垂直位置 ()
水平座标 ＝ 取鼠标水平位置 ()
.如果真 (是否为空 (是否拉伸))
    是否拉伸 ＝ 假
.如果真结束
.如果真 (是否为空 (是否置顶))
    是否置顶 ＝ 真
.如果真结束

.如果真 (水平座标 ＜ 窗口.左边 或 水平座标 ＞ 窗口.左边 ＋ 窗口.宽度 或 垂直座标 ＜ 窗口.顶边 或 垂直座标 ＞ 窗口.顶边 ＋ 窗口.高度)
    .判断开始 (窗口.顶边 ≤ 0)  ' 靠上隐藏
        窗口.移动 (, 4 － 窗口.高度, , )
        窗口.总在最前 ＝ 是否置顶
        方位 ＝ “上”
    .判断 (窗口.左边 ≤ 0)  ' 靠左隐藏
        窗口.左边 ＝ 4 － 窗口.宽度
        窗口.总在最前 ＝ 是否置顶
        .如果真 (是否拉伸 ＝ 真)
            窗口.移动 (, 1, , 取屏幕高度 () － 29)  ' 减去 任务栏高度+1
        .如果真结束
        方位 ＝ “左”
    .判断 (窗口.左边 ≥ 取屏幕宽度 () － 窗口.宽度)  ' 靠右隐藏
        窗口.左边 ＝ 取屏幕宽度 () － 4
        窗口.总在最前 ＝ 是否置顶
        .如果真 (是否拉伸 ＝ 真)
            窗口.移动 (, 1, , 取屏幕高度 () － 29)  ' 减去 任务栏高度+1
        .如果真结束
        方位 ＝ “右”
    .默认

    .判断结束
    返回 ()
.如果真结束
.判断开始 (方位 ＝ “上”)
    窗口.移动 (, 0, , )
.判断 (方位 ＝ “左”)
    窗口.移动 (0, , , )
.判断 (方位 ＝ “右”)
    窗口.移动 (取屏幕宽度 () － 窗口.宽度, , , )
.默认
.判断结束
方位 ＝ “”
窗口.总在最前 ＝ 假