高级信息框/对话框功能扩展模块

.子程序 高级浏览文件夹, 文本型, 公开, 打开高级浏览文件夹对话框并返回当前用户选择的文件夹或文件名。如果用户取消操作或选择错误，将返回空值。
.参数 窗口句柄, 整数型
.参数 窗口标题, 文本型, 可空, 指定当对话框创建后，显示的标题文字。
.参数 初始目录, 文本型, 可空, 指定当对话框创建后，自动跳转到的目录。
.参数 是否显示文件, 逻辑型, 可空, 默认为假
.参数 是否显示地址栏, 逻辑型, 可空, 默认为真
.参数 是否使用新样式, 逻辑型, 可空, 默认为真
.局部变量 部_浏览文件夹, 类型_浏览文件夹
.局部变量 部_被选择对象, 文本型

集_初始目录 ＝ 选择 (是否为空 (初始目录), “”, 初始目录)
是否显示文件 ＝ 选择 (是否为空 (是否显示文件), 假, 是否显示文件)
是否显示地址栏 ＝ 选择 (是否为空 (是否显示地址栏), 真, 是否显示地址栏)
是否使用新样式 ＝ 选择 (是否为空 (是否使用新样式), 真, 是否使用新样式)
' ========>>>>>>>>
部_浏览文件夹.hwndOwner ＝ 窗口句柄
部_浏览文件夹.lpszTitle ＝ 选择 (是否为空 (窗口标题), “请选择一个文件夹”, 窗口标题)
部_浏览文件夹.lpfn ＝ &高级浏览文件夹_回调函数 ' 高级浏览文件夹_回调函数 是子程序不是方法，因此不能写在本类里面。
部_浏览文件夹.ulFlags ＝ 位或 (选择 (是否显示地址栏, 16, 0), 选择 (是否使用新样式, 64, 0), 选择 (是否显示文件, 16384, 0))
' ========>>>>>>>>
部_被选择对象 ＝ 取空白文本 (512) ' 此行代码必须存在！
.如果真 (API_SHGetPathFromIDList (API_SHBrowseForFolder (部_浏览文件夹), 部_被选择对象) ＝ 0)
返回 (“”)
.如果真结束
返回 (删首尾空 (部_被选择对象))

.子程序 高级信息框, 整数型, 公开, 打开高级信息框并可以指定时间内返回；当信息框仅具备确认钮且指定显示时间参数时，无论是否操作均返回#确认钮，其它返回值与易语言信息框通用。
.参数 窗口句柄, 整数型
.参数 提示信息, 文本型, , 提示信息只能为文本。如果提示信息为文本且包含多行，可在各行之间用回车符 (即“字符 (13)”)、换行符 (即“字符 (10)”) 或回车换行符的组合 (即：“字符 (13) + 字符 (10)”) 来分隔。
.参数 按钮类型, 整数型, 可空, 第一组（描述对话框中显示按钮的类型与数目）：0、#确认钮 1、#确认取消钮 2、#放弃重试忽略钮 3、#取消是否钮 4、#是否钮 5、#重试取消钮；第二组（描述图标的样式）：16、#错误图标 32、#询问图标 48、#警告图标 64、#信息图标；默认为#确认钮
.参数 窗口标题, 文本型, 可空, 信息框的标题文本，默认显示“信息：”。
.参数 显示时间, 整数型, 可空, 指定信息框的显示时间，单位为毫秒(1秒=1000毫秒)，默认显示时间为10秒。
.局部变量 部_返回代码, 整数型

' ' #确认取消钮 1 #放弃重试忽略钮 2 #取消是否钮 3 #是否钮 4 #重试取消钮 5
' ' #错误图标 16 #询问图标 32 #警告图标 48 #信息图标 64
' ' #确认钮 0 #取消钮 1 #放弃钮 2 #重试钮 3 #忽略钮 4 #是钮 5 #否钮 6
' ========>>>>>>>>
窗口标题 ＝ 选择 (窗口标题 ＝ “”, “信息：”, 窗口标题)

显示时间 ＝ 选择 (是否为空 (显示时间), 10000, 显示时间)
部_返回代码 ＝ API_MessageBoxTimeout (窗口句柄, 提示信息, 窗口标题, 按钮类型, 0, 显示时间)
.如果真 (按钮类型 ＝ 0 或 按钮类型 ＝ 16 或 按钮类型 ＝ 32 或 按钮类型 ＝ 48 或 按钮类型 ＝ 64) ' #确认钮
返回 (部_返回代码 － 1)
.如果真结束
' ========>>>>>>>>
.如果真 (部_返回代码 ≠ 32000)
部_返回代码 ＝ 部_返回代码 － 1 ' 因易语言的返回值比API大1，所以需要减1才可以与易保持一致。
.如果真结束
' ========>>>>>>>>
返回 (部_返回代码)