大威天龙特效GIF拆分启动窗口

.子程序 处理_拆分GIF, 整数型
.参数 参_图片, 字节集
.参数 参_返回帧图片数组, 字节集, 参考 数组
.参数 参_标识, 文本型, 参考, 每个图片都有他的标识，如gif图片的标识就是“GIF” ，png的图片就是png类似这样
.参数 参_版本号, 文本型, 参考, 返回gif的版本号
.参数 参_宽度, 整数型, 参考, 返回gif的宽度
.参数 参_高度, 整数型, 参考, 返回gif的高度
.局部变量 局_临时字节集, 字节集
.局部变量 局_头部, 字节集
.局部变量 i, 整数型
.局部变量 局_帧界位置, 整数型, , "0"
.局部变量 局_累计, 整数型
.局部变量 局_帧位置, 整数型, , "0"
.局部变量 局_成员数, 整数型

局_临时字节集 ＝ 参_图片
参_标识 ＝ 到文本 (取字节集左边 (局_临时字节集, 3))
参_版本号 ＝ 到文本 (取字节集中间 (局_临时字节集, 4, 3))
参_宽度 ＝ 到整数 (取字节集数据 (取字节集中间 (局_临时字节集, 7, 2), #长整数型, ))
参_高度 ＝ 到整数 (取字节集数据 (取字节集中间 (局_临时字节集, 9, 2), #长整数型, ))
局_头部 ＝ 取字节集左边 (局_临时字节集, 寻找字节集 (局_临时字节集, { 0, 33, 249, 4 }, ))
.判断循环首 (真)
i ＝ i ＋ 1
加入成员 (局_帧界位置, 寻找字节集 (局_临时字节集, { 0, 33, 249, 4 }, ))
.如果真 (局_帧界位置 [i] ＝ -1)
跳出循环 ()
.如果真结束
局_临时字节集 ＝ 取字节集右边 (局_临时字节集, 取字节集长度 (局_临时字节集) － 局_帧界位置 [i])
局_累计 ＝ 局_累计 ＋ 局_帧界位置 [i]
加入成员 (局_帧位置, 局_累计)
.判断循环尾 ()
局_成员数 ＝ 取数组成员数 (局_帧位置)
重定义数组 (参_返回帧图片数组, 假, 局_成员数)
i ＝ 0
.计次循环首 (局_成员数, i)
.如果真 (i ＝ 局_成员数)
参_返回帧图片数组 [局_成员数] ＝ 局_头部 ＋ 取字节集右边 (参_图片, 取字节集长度 (参_图片) － 局_帧位置 [i])
跳出循环 ()
.如果真结束
参_返回帧图片数组 [i] ＝ 局_头部 ＋ 取字节集中间 (参_图片, 局_帧位置 [i] ＋ 1, 局_帧位置 [i ＋ 1] － 局_帧位置 [i]) ＋ { 59 }
.计次循环尾 ()